**Revit 2011 API Intro Labs**

**Lab2 – DB Element**

July, 2010 by M. Harada

**<VB.NET>**VB.NET Version**</VB.NET>**

**Objective:** In this lab, we will learn how an element is represented in Revit and how to retrieve information about an element. We’ll learn how to:

* Identify an element
* Retrieve a set of properties of an element
* Retrieve a specific property of an element
* Retrieve location information
* Retrieve geometry information

**Tasks:** We’ll write a command that prompts the user to pick an element, identify the kind of element, and displays its information about properties, location and geometry:

1. Pick an element.
2. Show basic information about the element and its family type (i.e., class name, category and element Id).
3. Identify the element that you have picked. (e.g., is it a wall, window or door?)
4. Show the set of properties of the element and its family type.
5. Show specific properties of the element and its family type.
6. Show the location information of the element
7. Show the geometry information of the element (Optional)

Figure 1 and 2 shows the sample images of output after running the command that you will be defining in this lab: 

Figure 1. Dialogs showing basic information and identity of an element.




Figure 2. Dialogs showing properties (or parameters) of an element and of its type

The following is the breakdown of step by step instructions in this lab:

[MH: To do after the main text is done.]

1. Define A New External Command
2. Pick an Element
3. Basic Element Information
4. Identify Element
5. Parameters
6. Location Information
7. Geometry Information (Optional)
8. Summary
9. **Define A New External Command**

We’ll add another external command to the current project.

* 1. Add a new file and define another external command to your project. Let’s name them as follows:
* File name: **2\_DB Element.vb (or .cs)**
* Command class name: **DBElement**

(Once again, you may choose to use any names you want here. When you do so, just remember what you are calling your own project, and substitute these names as needed while following the instruction in this document.)

**Required Namespaces:**

Namespaces needed for this lab are:

* (System.Linq) (needed for Lab3)
* Autodesk.Revit.DB
* Autodesk.Revit.UI
* Autodesk.Revit.ApplicationServices
* Autodesk.Revit.Attributes
* Autodesk.Revit.UI.Selection (this is for selection)

Note (VB.NET only): if you are writing in VB.NET and you import namespaces at the project level, (i.e., in the project properties, there is no need to explicitly import in each file.

* 1. To keep the top level object access throughout this document or the class, we define member variables to the class. Revit has a concept of separation between DB and UI objects. This applies to the Revit application and document objects. These top level objects are accessible as follows:
* UIApplication 🡨 commandData.Application
* Application 🡨UIApplication.Application
* UIDocument 🡨 UIApplication.ActiveUIDocument
* Document 🡨 UIDocument.Document

Define member variables, e.g., m\_rvtApp and m\_rvtDoc, to keep save DB level application and document respectively. The following is an example:

**<VB.NET>**

'' DB Element – learn about Revit element

<Transaction(TransactionMode.Automatic)> \_

<Regeneration(RegenerationOption.Manual)> \_

Public Class DBElement

Implements IExternalCommand

**'' member variables**

**Dim m\_rvtApp As Application**

**Dim m\_rvtDoc As Document**

Public Function Execute(ByVal commandData As ExternalCommandData, \_

ByRef message As String, \_

ByVal elements As ElementSet) \_

As Result \_

Implements IExternalCommand.Execute

'' Get the access to the top most objects.

**Dim rvtUIApp As UIApplication = commandData.Application**

**Dim rvtUIDoc As UIDocument = rvtUIApp.ActiveUIDocument**

**m\_rvtApp = rvtUIApp.Application**

**m\_rvtDoc = rvtUIDoc.Document**

'' ...

Return Result.Succeeded

End Function

End Class  
**</VB.NET>**

1. **Pick an Element**

**DB.Element** is a base class for objects in the Revit project database. We are going to pick an arbitrary element on the UI screen and examine it to learn more about elements in Revit.

We can use one of overloaded PickObject() method to pick an object on the screen:

* UIDocument.Selection.PickObject(ObjectType.Element, promptString)

(We’ll come to the topic of UI and selection when we get into the UI portion of the training. For now, this should be enough for the purpose of this lab.)

The following code demonstrates the usage:

**<VB.NET>** '' (1) pick an object on a screen.

Dim ref As Reference = \_

rvtUIDoc.Selection.PickObject(ObjectType.Element, "Pick an element")

'' we have picked something.

Dim elem As Element = ref.Element  
**</VB.NET>**

PickObject() returns Reference object. You can retrieve the Element from the reference object returned.

1. **Basic Element Information**

In typical programming or usage of APIs, we identify the given object by checking its class names. Does the same apply to Revit API? The exercise in this section will answer this question.

3.1 Write a function which takes Element as an argument, and display the following properties of the given element:

* Class name (or Type in .NET)
* Category name
* Id (Element Id)

Then do the same with the family type of the given element. To get to the family type of the given element, you can use Element.GetTypeId() to obtain its Id first, then use Document.Element(elementId).   
Let’s name this function it, for example, **ShowBasicElementInfo()**. The following shows a sample code to do this:

**<VB.NET>**

Public Sub ShowBasicElementInfo(ByVal elem As Element)

'' let's see what kind of element we got.

Dim s As String = "You picked:" + vbCr

s = s + " Class name = " + elem.GetType.Name + vbCr

s = s + " Category = " + elem.Category.Name + vbCr

s = s + " Element id = " + elem.Id.ToString + vbCr + vbCr

'' and check its type info.

Dim elemTypeId As ElementId = elem.GetTypeId

Dim elemType As ElementType = m\_rvtDoc.Element(elemTypeId)

s = s + "Its ElementType:" + vbCr

s = s + " Class name = " + elemType.GetType.Name + vbCr

s = s + " Category = " + elemType.Category.Name + vbCr

s = s + " Element type id = " + elemType.Id.ToString + vbCr

'' show what we got.

TaskDialog.Show("Revit Intro Lab", s)

End Sub

**</VB.NET>**

Then, call this function from your main Execute() method right after you have picked an element:

**<VB.NET>**

'' we have picked something.

Dim elem As Element = ref.Element

'' (2) let's see what kind of element we got.

ShowBasicElementInfo(elem)

**</VB.NET>**

3.2 Build the project. Add manifest file, e.g.:

<AddIn Type="Command">

<Text>DB Element</Text>

<FullClassName>RevitIntroVB.DBElement</FullClassName>

<Assembly>D:\RevitAPI 2011\Training\Labs\Revit Intro Labs\RevitIntro\RevitIntroVB\bin\Debug\RevitIntroVB.dll</Assembly>

<AddInId>827AC040-6F44-4c03-82FE-292705580800</AddInId>

</AddIn>

Run the command, “DB Element”. Pick an element. Then, you will see a dialog like following showing the class, category and id of the element that you just picked (Figure 3). Try picking up a few other element and observe the output.




Figure3. Dialog showing the a few properties from a door.

**Discussion:**

* Compare the class names and categories among different elements, such as walls, doors and windows. What do you observe?
* Could you identify the element from the class name?
* Could you identify the element from the category?

Discuss these with your colleagues and instructor.

1. **Identify Element**

As you have found out by now, a class name is not enough to identify an element in Revit. Depending on an element you have, you will need to check the following:

* Class name
* Category
* If an element is Element Type (Symbol) or not

Table 1 shows the examples of a few elements with their class names and categories used to identify the element. They are divided into four areas: System Family vs. Component Family, and Family Type vs. Instance. This probably gives you slightly clear view of why you can identity some element by the class name and some requires category.

* A system family are a built-in object in Revit. There is a designated class for it. You can use it to identify the element.
* A component family has a generic form as FamilyInstance/FamilySymbol. Category is the way to further identify the kind of object it is representing in Revit.

|  |  |  |
| --- | --- | --- |
|  | **System Family** | **Component Family** |
| **Family Type** | WallType FloorType | FamilySymbol &  Category - Doors, Windows |
| **Instance** | Wall Floor | FamilyInstance &  Category - Doors, Windows |

Table 1. class names and categories that you can use to identify   
an element for walls, floors, doors and windows.

Now that we have understood how an element is represented in Revit database, let’s add a code to identify an element. Here is an example:

**<VB.NET>**

'' identify the type of the element known to the UI.

Public Sub IdentifyElement(ByVal elem As Element)

'' An instance of a system family has a designated class.

'' You can use it identify the type of element.

'' e.g., walls, floors, roofs.

''

Dim s As String = ""

If TypeOf elem Is Wall Then

s = "Wall"

ElseIf TypeOf elem Is Floor Then

s = "Floor"

ElseIf TypeOf elem Is RoofBase Then

s = "Roof"

ElseIf TypeOf elem Is FamilyInstance Then

'' An instance of a component family is all FamilyInstance.

'' We'll need to further check its category.

'' e.g., Doors, Windows, Furnitures.

If elem.Category.Id.IntegerValue = \_

BuiltInCategory.OST\_Doors Then

s = "Door"

ElseIf elem.Category.Id.IntegerValue = \_

BuiltInCategory.OST\_Windows Then

s = "Window"

ElseIf elem.Category.Id.IntegerValue = \_

BuiltInCategory.OST\_Furniture Then

s = "Furniture"

Else

s = "Component family instance" '' e.g. Plant

End If

'' check the base class. e.g., CeilingAndFloor.

ElseIf TypeOf elem Is HostObject Then

s = "System family instance"

Else

s = "Other"

End If

s = "You have picked: " + s

'' show it.

TaskDialog.Show("Revit Intro Lab", s)

End Sub

**</VB.NET>**

Call this function from your main Execute() method right after ShowBasicElementInfo():

**<VB.NET>**

'' (2) let's see what kind of element we got.

ShowBasicElementInfo(elem)

'' (3) identify each major types of element.

IdentifyElement(elem)

**</VB.NET>**

Build and run the command “DB Element” once again to see if you can identify an element you have picked. Figure 4 shows an sample images of running the command.



Figure 4. Identifying an element

1. **Parameters**

Parameters property of an Element class largely corresponds to an element or family “properties” that you see in the UI. In the Revit API, there are two ways to access those properties or parameters:

* Element.Parameters – returns a set of parameters applicable to the given element.
* Element.Paramater – takes an argument that can identify the kind of parameter and returns the value of single parameter.
  1. Retrieving a Set of Parameters through Parameters()

Let’s first look at the Parameters(). The code below demonstrates the usage. Parameters() return a set of parameters. You can simply loop through it to access each paramater. The main part that you will need to pay attention is that that you will need to parse each parameter by the StrageType; a parameter can be Integer, Double, String and ElementId. Depending on the StrageType, you will need to choose the method to get the actual value.

**<VB.NET>**

'' show all the parameter values of the element

Public Sub ShowParameters(ByVal elem As Element, Optional ByVal header As String = "")

Dim s As String = header + vbCr + vbCr

Dim params As ParameterSet = elem.Parameters

For Each param As Parameter In params

Dim name As String = param.Definition.Name

'' see the helper function below

Dim val As String = ParameterToString(param)

s = s + name + " = " + val + vbCr

Next

TaskDialog.Show("Revit Intro Lab", s)

End Sub

''

'' Helper function: return a string from of a given parameter.

''

Public Shared Function ParameterToString(ByVal param As Parameter) As String

Dim val As String = "none"

If param Is Nothing Then

Return val

End If

'' to get to the parameter value, we need to pause it depending on

'' its strage type

Select Case param.StorageType

Case StorageType.Double

Dim dVal As Double = param.AsDouble

val = dVal.ToString

Case StorageType.Integer

Dim iVal As Integer = param.AsInteger

val = iVal.ToString()

Case StorageType.String

Dim sVal As String = param.AsString

val = sVal

Case StorageType.ElementId

Dim idVal As ElementId = param.AsElementId

val = idVal.IntegerValue.ToString

Case StorageType.None

Case Else

End Select

Return val

End Function

**</VB.NET>**

[MH: need to look at optional parameter in C#. Maybe we don’t need to do anything?]

Call this function from your main Execute() method after IdentifyElement(). You may also use the same function to display its family type information.

**<VB.NET>**

'' (3) identify each major types of element.

IdentifyElement(elem)

'' (4) first parameters.

ShowParameters(elem, "Element Parameters: ")

'' check to see its type parameter as well

''

Dim elemTypeId As ElementId = elem.GetTypeId

Dim elemType As ElementType = m\_rvtDoc.Element(elemTypeId)

ShowParameters(elemType, "Type Parameters: ")

**</VB.NET>**

Build and run the command “DB Element” once again. You should be a list of parameters displayed in dialogs. Figure 2 (on page 2) shows a sample images of running the command.

* 1. Retrieving an Individual Parameter Using BuiltInParameter

There are four ways to access individual parameters:

* Parameter(**BuiltInParameter**) – retrieve a parameter using the parameter Id.
* Parameter(String) – retrieve using the name.
* Parameter(Definition) – retrieve from its definition.
* Parameter(GUID) – retrieve shared parameter using GUID.

Here will take a look at the first and second. Calling parameter(Xxx) method itself using the name is straightforward. However, using name has a disadvantage of depending on a language version of Revit you are running. Therefore, using BuiltInParameter is more ideal. The trick here is to find out which parameter Id or BuiltInParameter to use. If you look at the RevitAPI.chm documentation, under BuiltInParameter Enum section, you will see hundreds of BuiltinParameters defined there with no description whatsoever. Among those BuiltInParameters, only fraction of enum are applicable to a given element. How can we find out which BuiltInParameter to use to retrieve a specific parameter?

**RevitLookup** tool comes handy to explore and find out which BuiltInParameter corresponds to which parameter name. When you want to find out a parameter for a specific type of element, simple click on the same type of object in the project >> [Snoop Current Selection …] >> [Parameters]. When you click on each parameter name, you can check its [Definition] to find out the corresponding BuiltInParameter (Figure 5).




Figure 5. Use RevitLookup to check the definition of parameter.

Another thing that may worth mentioning that if you look at the list of BuiltInParameters, using [Built-in Enums Snoop…] or [Built-in Enumes Map…] button, you will see more parameters than you see in parameters list. Occasionally, you may find some useful properties there. Such a sample will be:

* BuiltInParameter.SYMBOL\_FAMILY\_AND\_TYPE\_NAMES\_PARAM – family and type name
* BuiltInParameter.SYMBOL\_FAMILY\_NAME\_PARAM – family name

You can use these to retrieve family and type names of the given element. Figure 6 shows a sample enum mapping.




Figure 6. you can use RevitLookup to explore which BuiltInParameter to use.

Below is a sampler that shows how to retrieve some of commonly used properties. Explore the BuiltInParameters in RevitLookup and try writing a function to retrieve a few parameters of your interests using the code below as an example.

**<VB.NET>**

'' examples of retrieving a specific parameter indivisually.

'' (harding coding for simplicity. This function works best with walls and doors.)

''

Public Sub RetrieveParameter(ByVal elem As Element, Optional ByVal header As String = "")

Dim s As String = header + vbCr + vbCr

'' as an experiment, let's pick up some arbitrary parameters.

'' comments - most of instance has this parameter

'' (1) by BuiltInParameter.

Dim param As Parameter = elem.Parameter(BuiltInParameter.ALL\_MODEL\_INSTANCE\_COMMENTS)

If param IsNot Nothing Then

s = s + "Comments (by BuiltInParameter) = " + ParameterToString(param) + vbCr

End If

'' (2) by name. (Mark - most of instance has this parameter.)

'' if you use this method, it will language specific.

param = elem.Parameter("Mark")

If param IsNot Nothing Then

s = s + "Mark (by Name) = " + ParameterToString(param) + vbCr

End If

'' the following should be in most of type parameter

''

param = elem.Parameter(BuiltInParameter.ALL\_MODEL\_TYPE\_COMMENTS)

If param IsNot Nothing Then

s = s + "Type Comments (by BuiltInParameter) = " + ParameterToString(param) + vbCr

End If

param = elem.Parameter("Fire Rating")

If param IsNot Nothing Then

s = s + "Fire Rating (by Name) = " + ParameterToString(param) + vbCr

End If

'' using the BuiltInParameter, you can sometimes access one that is not in the parameters set.

'' Note: this works only for element type.

'' [MH3i: To Do - check c# version. 4/26. ]

param = elem.Parameter(BuiltInParameter.SYMBOL\_FAMILY\_AND\_TYPE\_NAMES\_PARAM)

If param IsNot Nothing Then

s = s + "SYMBOL\_FAMILY\_AND\_TYPE\_NAMES\_PARAM (only by BuiltInParameter) = " + \_

ParameterToString(param) + vbCr

End If

param = elem.Parameter(BuiltInParameter.SYMBOL\_FAMILY\_NAME\_PARAM)

If param IsNot Nothing Then

s = s + "SYMBOL\_FAMILY\_NAME\_PARAM (only by BuiltInParameter) = " + \_

ParameterToString(param) + vbCr

End If

'' show it.

TaskDialog.Show("Revit Intro Lab", s)

End Sub

**</VB.NET>**

Call your function from your main Execute() method at the end. You may also use the same function to display its family type information.

**<VB.NET>**

'' (4) first parameters.

ShowParameters(elem, "Element Parameters: ")

'' check to see its type parameter as well

''

Dim elemTypeId As ElementId = elem.GetTypeId

Dim elemType As ElementType = m\_rvtDoc.Element(elemTypeId)

ShowParameters(elemType, "Type Parameters: ")

'' access to each parameters.

RetrieveParameter(elem, "Element Parameter (by Name and BuiltInParameter): ")

'' the same logic applies to the type parameter.

RetrieveParameter(elemType, "Type Parameter (by Name and BuiltInParameter): ")

**</VB.NET>**

Build and run the command “DB Element” once again. You should be a list of parameters of your choice displayed in dialogs (Figure7).




Figure 7. You can use BuiltInParameters to access parameters individually.

1. **Location Information**

Location of each element is stored under Location property. A location can be point-based (LocationPoint) or curve/line-based (LocationCurve). You will need to cast to LocationPoint or LocationCurve in order to access more properties. The following demonstrates the usage:

**<VB.NET>**

'' show the location information of the given element.

'' location can be LocationPoint (e.g., furniture), and LocationCurve

'' (e.g., wall).

Public Sub ShowLocation(ByVal elem As Element)

Dim s As String = "Location Information: " + vbCr + vbCr

Dim loc As Location = elem.Location

If TypeOf loc Is LocationPoint Then

'' (1) we have a location point

''

Dim locPoint As LocationPoint = loc

Dim pt As XYZ = locPoint.Point

Dim r As Double = locPoint.Rotation

s = s + "LocationPoint" + vbCr

s = s + "Point = " + PointToString(pt) + vbCr

s = s + "Rotation = " + r.ToString + vbCr

ElseIf TypeOf loc Is LocationCurve Then

'' (2) we have a location curve

''

Dim locCurve As LocationCurve = loc

Dim crv As Curve = locCurve.Curve

s = s + "LocationCurve" + vbCr

s = s + "EndPoint(0)/Start Point = " + \_  
 PointToString(crv.EndPoint(0)) + vbCr

s = s + "EndPoint(1)/End point = " + \_  
 PointToString(crv.EndPoint(1)) + vbCr

s = s + "Length = " + crv.Length.ToString + vbCr

'' check join type [MH3i: To Do - add in C# 4/26]

s = s + "JoinType(0) = " + locCurve.JoinType(0).ToString + vbCr

s = s + "JoinType(1) = " + locCurve.JoinType(1).ToString + vbCr

End If

'' show it

TaskDialog.Show("Revit Intro Lab", s)

End Sub

'' Helper Function: returns XYZ in a string form.

''

Public Shared Function PointToString(ByVal pt As XYZ) As String

If pt Is Nothing Then

Return ""

End If

Return "(" + pt.X.ToString("F2") + ", " + pt.Y.ToString("F2") + \_

", " + pt.Z.ToString("F2") + ")"

End Function

**</VB.NET>**

Call your function from your main Execute() method at the end.

**<VB.NET>**

'' (4) first parameters.

...

'' the same logic applies to the type parameter.


RetrieveParameter(elemType, "Type Parameter (by Name and BuiltInParameter): ")

'' (5) location

ShowLocation(elem)

**</VB.NET>**

Build and run the command “DB Element” once again. You should be location information displayed in dialogs. (Figure 8)

  
Figure 8. Sample location info.

1. **Geometry Information (Optional)**

The last piece of information that we would like to take a look is Geometry. Writing a code for retrieving Geometry information can get a little involved and beyond the scope of this training. We‘ll only describe a big picture here.

* Geometry Options – you can specify the detail level (Fine, Medium and Fine) when you retrieve geometry information from an element.
* A Geometry object can be Solid, Geometry Instance, Curve or Mesh. Geometry Instance is a instance of another element (symbol), such as a window and a door.

The code below shows the access up to the high level geometry representation. For further drill down of Solids/Faces/Edges, please use RevitLookup. RevitCommands sample has a simple example. The following samples show other geometry access with a little viewer:

* ElementViewer
* RoomViewer
* AnalyticalViewer

**<VB.NET>**

'' show the geometry information of the given element.

Public Sub ShowGeometry(ByVal elem As Element)

Dim s As String = "Geometry Information: " + vbCr + vbCr

'' first, set a geometry option

Dim opt As Options = m\_rvtApp.Create.NewGeometryOptions

opt.DetailLevel = DetailLevels.Fine

'' does the element have the geometry data?

Dim geomElem As GeometryElement = elem.Geometry(opt)

If geomElem Is Nothing Then

TaskDialog.Show("Revit Intro Lab", s + "no data")

Return

End If

'' get the geometry information from the geom elem.

'' geometry informaion can easily go into depth.

'' here we look at at top level. use RevitLookup for complee dril down.

''

s = GeometryElementToString(geomElem)

'' show it.

TaskDialog.Show("Revit Intro Lab", s)

End Sub

'' Helper Function: parse the geometry element by geometry type.

'' see ReviCommands in the SDK sample for complete implementation.

''

Public Shared Function GeometryElementToString(ByVal geomElem As GeometryElement) As String

Dim geomObjs As GeometryObjectArray = geomElem.Objects

Dim str As String = "Total number of GeometryObject: " & geomObjs.Size.ToString & vbCr

For Each geomObj As GeometryObject In geomObjs

If TypeOf geomObj Is Solid Then ' ex. wall

Dim solid As Solid = geomObj

'str = str & GeometrySolidToString(solid)

str = str + "Solid" + vbCr

ElseIf TypeOf geomObj Is GeometryInstance Then ' ex. door/window

str = str & " -- Geometry.Instance -- " & vbCr

Dim geomInstance As GeometryInstance = geomObj

Dim geoElem As GeometryElement = geomInstance.SymbolGeometry()

str = str & GeometryElementToString(geoElem)

ElseIf TypeOf geomObj Is Curve Then ' ex.

Dim curv As Curve = geomObj

'str = str & GeometryCurveToString(curv)

str = str + "Curve" + vbCr

ElseIf TypeOf geomObj Is Mesh Then ' ex.

Dim mesh As Mesh = geomObj

'str = str & GeometryMeshToString(mesh)

str = str + "Mesh" + vbCr

Else

str = str & " \*\*\* unkown geometry type" & geomObj.GetType.ToString

End If

Next

Return str

End Function

**</VB.NET>**

Call your function from the end of your main Execute() method.

**<VB.NET>**

'' (5) location

ShowLocation(elem)

'' (6) geometry - the last piece. (Optional)

ShowGeometry(elem)

**</VB.NET>**

Build and run the command “DB Element” once again. You should be geometry information displayed in dialogs. (Figure 9).




Figure 9. an example of high level geometry information

1. **Summary**

In this lab, we have learned how an element is represented in Revit and how to retrieve information about an element. We have learned how to:

* Identify an element using class name, category, and symbol or not.
* Retrieve a set of properties of an element using Parameters()
* Retrieve a specific property of an element using BuiltInParameter
* Retrieve location information
* Retrieve graphic information

In the next lab, we will take a look at a group of elements in the Revit database and learn how to selectively retrieve elements of our interests, which is called element filtering.

Autodesk Developer Network